ASP

404错误伪静态类封装class RewriteBase

作者:hayden 日期:2009-06-12

字体大小: 小中大

这是早上找了点时间写了一个利用404错误达到静态态效果的类，准备在HTTP://PJSKIN.MYSUC.COM中使用的。不过现在没时间去弄了，因为首页嘛，一般就用动态的了，但需要将里面的地址改成静态后的地址，麻烦啊，今天就不弄啦，不过基本的类框架都写好了，剩下的只是去写写规则，及更改首页的页面内容中出现的地址。

下面来看看该RewriteBase类的使用方法：

在404asp页面中首先引入RewriteBase类

复制内容到剪贴板

程序代码

然后在后面的ASP代码中按如下方面设置伪静态：

复制内容到剪贴板

程序代码

<%
Dim Rewrite
Set Rewrite = new RewriteBase    '建立对象
    'Rewrite.Char "utf-8"    '设置编码默认为utf-8
    '假设访问网址：http://pjskin.mysuc.com/style_1149.shtml
    'Rewrite.ourl  '这里可以测试最初所接收的地址，如我的空间404后该函数所接收到的地址是这样的：http://202.91.239.125/404.asp?404;http://pjskin.mysuc.com:80/style_1149.shtml=
    Rewrite.ReSetUrl "http[^;]*;([^=]*)=","$1"    '通过上面的地址，设置一个正则转换，使其变成我们在浏览器中所点击的地址。如果你的空间没有此问题，这一步可以去掉。
    'Rewrite.ourl    '这里可以测试是否成功转换为所点击的地址。如结果显示为：http://pjskin.mysuc.com/style_1149.shtml

    '**************************
    '伪静态正则规则开始。
    '**************************

    Rewrite.Rule "(http:[^:]*):80\/style_([0-9]+)\.shtml","$1/?styleid=$2"
    'Rewrite.ourl    '这里可以测试是否已转换到最后地址,将上一步格式的地址转化成如下：http://pjskin.mysuc.com/styleid=1149

    '下面的规则是我按PJBLOG的地址写了一个规则，不过有待测试。
    'Rewrite.Rule "^\/article\/([0-9]+)\.htm","/article.asp?id=$1"
    'Rewrite.Rule "^\/class_([0-9]+)\.html$","/default.asp?cateID=$1"
    'Rewrite.Rule "^\/tag\.htm$","/tag.asp"
    'Rewrite.Rule "^\/GuestBook\.html$","/LoadMod.asp?plugins=GuestBookForPJBlog"
    'Rewrite.Rule "^\/AboutMe\.html$","/LoadMod.asp?plugins=AboutMeForPJBlog"
    'Rewrite.Rule "^\/tag_([^\.])*\.html$","/default.asp?tag=$1"

    '**************************
    '转换页面中存在的动态地址
    '**************************
　　'利用Rewrite.Src 函数，转换输出的页面内容中的链接网址。如果已在源码中都修改了，在这里就不需要设置。
    Rewrite.Src "(href=""[^\?]*)\?styleid=([0-9]+)","$1style_$2.shtml"    '将页面里的地址转成伪静态格式的地址。

Set Rewrite = Nothing
%>

有兴趣的朋友可以下载RewriteBase类源码玩玩：
压缩包类包括：404.asp、cls_RewriteBase.asp

下载文件

点击下载此文件

在线测试地址：http://pjskin.mysuc.com/style_1075.shtml#comm_84　注意看里面的链接，目前只写了一条规则（就是上面示例中的）

404.asp源码：

HTML代码

<%@ LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<%
Option Explicit
Session.CodePage = 65001
%>

<%
Dim Rewrite
Set Rewrite = new RewriteBase
	'Rewrite.Char "utf-8"	'设置编码默认为utf-8
	'Rewrite.ourl  '这里可以测试最初所接收的地址，如我的空间是这样的：http://202.91.239.125/404.asp?404;http://pjskin.mysuc.com:80/style_1149=
	Rewrite.ReSetUrl "http[^;]*;([^=]*)=","$1"	'通过正则转换
	'Rewrite.ourl	'这里可以测试是否成功转换为所点击的地址。如：http://pjskin.mysuc.com/style_1149.shtml

'**************************
	'伪静态正则规则开始。
	'**************************

Rewrite.Rule "(http:[^:]*):80\/style_([0-9]+)\.shtml","$1/?styleid=$2"
	'Rewrite.ourl	'这里可以测试是否已转换到最后地址,将上一步格式的地址转化成如下：http://pjskin.mysuc.com/styleid=1149

'Rewrite.Rule "^\/article\/([0-9]+)\.htm","/article.asp?id=$1"
	'Rewrite.Rule "^\/class_([0-9]+)\.html$","/default.asp?cateID=$1"
	'Rewrite.Rule "^\/tag\.htm$","/tag.asp"
	'Rewrite.Rule "^\/GuestBook\.html$","/LoadMod.asp?plugins=GuestBookForPJBlog"
	'Rewrite.Rule "^\/AboutMe\.html$","/LoadMod.asp?plugins=AboutMeForPJBlog"
	'Rewrite.Rule "^\/tag_([^\.])*\.html$","/default.asp?tag=$1"

'**************************
	'转换页面中存在的动态地址
	'**************************
	Rewrite.Src "(href=""[^\?]*)\?styleid=([0-9]+)","$1style_$2.shtml"	'将页面里的地址转成伪静态格式的地址。

Set Rewrite = Nothing 
%>

<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
 <head>
	<meta http-equiv="Content-Type" content="text/html; charset=UTF-8" />
	<meta http-equiv="Content-Language" content="UTF-8" />
	<title>404错误</title>
	<meta name="robots" content="all" />
	<meta name="generator" content="editplus" />
	<meta name="author" content="hayden@yeah.net,hayden" />
	<meta name="Copyright" content="mysuc.com" />
	<meta name="keywords" content="" />
	<meta name="description" content="" />
	<link rel="stylesheet" rev="stylesheet" href="" type="text/css" media="all" />
	<style type="text/css">

</style>
	<script type="text/javascript" src=""></script>
 </head>
 <body>
  404错误，您所查看的页面已失效。
 </body>

[Ctrl+A 全部选择提示：你可先修改部分代码，再按运行]

下面是cls_RewriteBase的源码：

HTML代码

<%
Class RewriteBase
'===========利用404错误伪静态类==========
'      Author:hayden
'      Copryright www.mysuc.com
'      Update: 2009-06-12
'===========================================
	Dim WebUrl,regEx,IsTransfer,Char,pagehtml
	Dim srt_sPattern,str_sContent
	Private Sub class_initialize() 
		Set regEx = New RegExp ' 建立正则表达式。 
		regEx.IgnoreCase = True ' 设置是否区分大小写。
		regEx.Global = True ' 设置全局可用性。 
		IsTransfer = False
		Char = "utf-8"
		GetUrl
		srt_sPattern = ""
		str_sContent = ""
	end sub

'编码设置
	Public Function Setchar(ByVal sChar)
		If Len(sChar)>0 Then Char = sChar
	End Function 
	
	'debug 输出真实地址
	Public Function ourl()
		Response.Status="200 OK"
		response.write WebUrl
		response.End 
	End Function

'正则处理伪静态
	Public Function rule(ByVal sPattern,ByVal sContent)
		If IsTransfer Then Exit Function
		IsTransfer = ReSetUrl(sPattern,sContent)
	End Function

'正则式处理
	Public Function ReSetUrl(ByVal sPattern,ByVal sContent)
		ReSetUrl = False
		regEx.Pattern = sPattern ' 设置模式。
		If regEx.Test(WebUrl) Then 
			WebUrl = regEx.Replace(WebUrl, sContent)
			ReSetUrl = True
		End If 
	End Function
	
	'整理正则式页面链接规则
	Public Function Src(ByVal sPattern,ByVal sContent)
		srt_sPattern = srt_sPattern & "|**|" & sPattern
		str_sContent = str_sContent & "|**|" & sContent
	End Function
	
	'正则式页面链接
	Private Function reSrc(ByVal sPattern,ByVal sContent)
		regEx.Pattern = sPattern ' 设置模式。
		pagehtml = regEx.Replace(pagehtml, sContent)
	End Function

'获取取目标URL地址的HTML代码
	Private Function steal(ByVal src_) 
		steal = ""
		If Not IsTransfer Then Exit Function
		dim Http
		set Http=server.createobject("MSXML2.XMLHTTP")
		Http.open "GET",src_ ,false
		Http.send()
		if Http.readystate<>4 then 
			exit Function
		end if
		steal=BytesToBSTR(Http.responseBody)
		set http=nothing
		if err.number<>0 then err.Clear
	end Function

'处理页面内容
	Private Function checkpage()
		If Not IsTransfer Then Exit Function
		pagehtml = steal(WebUrl)
		Dim i
		Dim arr_sPattern,arr_sContent
		If Len(srt_sPattern)>0 And Len(str_sContent)>0 Then 
			arr_sPattern = Split(srt_sPattern,"|**|")
			arr_sContent = Split(str_sContent,"|**|")
			For i = 1 To UBound(arr_sPattern)
				If Len(arr_sPattern(i))>0 Then reSrc arr_sPattern(i),arr_sContent(i)
			Next 
		End If 
	End Function
	
	'中文处理
	Private Function BytesToBstr(ByVal sbody)
		dim objstream
		set objstream = Server.CreateObject("adodb.stream")
		objstream.Type = 1
		objstream.Mode =3
		objstream.Open
		objstream.Write sbody
		objstream.Position = 0
		objstream.Type = 2
		objstream.Charset = Char
		BytesToBstr = objstream.ReadText 
		objstream.Close
		set objstream = nothing
	End Function

'获取当前网址
	Private Sub GetUrl()
		Dim strHostName,strScriptName,strSubUrl,strRequestItem 
		strHostName = CStr(Request.ServerVariables("LOCAL_ADDR"))
		strScriptName = CStr(Request.ServerVariables("SCRIPT_NAME"))
		strSubUrl=""
		If Request.QueryString <> "" Then
			strScriptName = strScriptName & "?"
			For Each strRequestItem In Request.QueryString
				If InStr(strScriptName,strRequestItem) = 0 Then
					If strSubUrl = "" Then
						strSubUrl = strSubUrl & strRequestItem & "=" & Server.URLEncode(Request.QueryString("" & strRequestItem & ""))
					Else
						strSubUrl = strSubUrl &"&" & strRequestItem & "=" & Server.URLEncode(Request.QueryString("" & strRequestItem & ""))
					End If
				End If
			Next
		End If
		WebUrl = "http://" & strHostName & strScriptName & strSubUrl
	End Sub

'建立跳转并关闭对象
	Private Sub class_terminate() 
		checkpage
		Set regEx = Nothing
		If IsTransfer Then
			response.write pagehtml
			response.End
		End If 
	end sub 
End Class
%>

[Ctrl+A 全部选择提示：你可先修改部分代码，再按运行]

博主向您推荐的其它文章

相关日志

评论: 10 | 引用: 0 | 查看次数: -

日志信息

[本日志由 hayden 于 2009-06-16 05:57 PM 编辑]

文章来自: 本站原创

引用通告: 查看所有引用 | 我要引用此文章

Tags: 伪静态 ASP asp类 RewriteBase 静态 class 封装

crazy1in.tk[2010-06-28 12:28 AM]

小弟不懂还是路过。www.crazy1in.tk

硅谷[2009-11-09 05:45 PM]

站长开发测试OK了吗？好用吗？想借鉴一下

hayden 于 2009-11-10 10:11 AM 回复

经测试，这方法在占用资源方面很存在问题呀！

dalier[2009-10-27 07:07 PM]

这个里有个问题...

就是编码,因为我有的页面是 GB2312, 有的是 UTF-8...

这样的情况该怎么办?

hayden 于 2009-11-10 10:13 AM 回复

这是个问题，需要转换编码~

zui[2009-08-19 10:40 PM]

xxx.com/article/123.html
xxx.com/article/asp/123.html

这样的效果，怎么写条件？

hayden 于 2009-11-10 10:12 AM 回复

Rewrite.Rule "^\/article\/([^\.])*\.html$","/article/asp/$1.html"

懒人猫[2009-06-22 05:37 PM]

blog.dzhai.com/class_31.html
blog.dzhai.com/article_491.html

测试了下，OK了，但有点问题

引用内容

Rewrite.Src "(href=""[^\?]*)\?styleid=([0-9]+)","$1style_$2.shtml" '将页面里的地址转成伪静态格式的地址。

我的页面里好像没有转换成功

hayden 于 2009-06-23 10:41 AM 回复

这应该是正则的问题，将你的正则式重新编写一下。

懒人猫[2009-06-22 04:51 PM]

因为要获取取目标URL地址的html代码，效率是个问题啊，还请指教一下~~~

vb[2009-06-15 09:04 AM]

这是一个好方法..

luoxiaoji[2009-06-14 08:49 PM]

额，不是博客的留言本程序了，
是你提供下载的那个留言本程序，怎么实现在留言框里加个可以改颜色的UBB功能。
还有就是只有管理员可见得功能~这2个功能非常需要。

luoxiaoji[2009-06-14 02:30 AM]

大哥, 你的留言可以怎么在留言框里加个设置颜色的UBB代码么。
我想要这个功能，怎么实现啊。

海天无影[2009-06-13 10:42 AM]

不知道什么意思
等样式出来我下看看吧

发表评论

Name (required)
PassWord(游客发言不需要密码.)
正在加载编辑器...

禁止表情转换禁止自动转换链接禁止自动转换关键字记住我的信息,以便下次评论时不用输入用户名.

虽然发表评论不用注册，但是为了保护您的发言权，建议您注册帐号.